VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "Touch"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit
' Modified by Alex Angelopouos from a form-based example 2002-03
Private Type FILETIME
  dwLowDateTime As Long
  dwHighDateTime As Long
End Type
Private Type SYSTEMTIME
  wYear As Integer
  wMonth As Integer
  wDayOfWeek As Integer
  wDay As Integer
  wHour As Integer
  wMinute As Integer
  wSecond As Integer
  wMilliseconds As Integer
End Type
Private Const GENERIC_WRITE = &H40000000
Private Const OPEN_EXISTING = 3
Private Const FILE_SHARE_READ = &H1
Private Const FILE_SHARE_WRITE = &H2
Private Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" (ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, ByVal lpSecurityAttributes As Long, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long
Private Declare Function SetFileTime Lib "kernel32" (ByVal hFile As Long, lpCreationTime As FILETIME, lpLastAccessTime As FILETIME, lpLastWriteTime As FILETIME) As Long
Private Declare Function SystemTimeToFileTime Lib "kernel32" (lpSystemTime As SYSTEMTIME, lpFileTime As FILETIME) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function LocalFileTimeToFileTime Lib "kernel32" (lpLocalFileTime As FILETIME, lpFileTime As FILETIME) As Long
Public Sub TouchNow(Filespec As String, Optional Timespec As String = "19800000000000")
  ' Simple modification to class form
  ' Alex K. Angelopoulos March 2002
  ' Resets times on a file to time specified in long semi-ISO format
  'KPD-Team 1998
  'URL: http://www.allapi.net/
  'KPDTeam@Allapi.net
  Dim m_Date As Date, lngHandle As Long
  Dim udtFileTime As FILETIME
  Dim udtLocalTime As FILETIME
  Dim udtSystemTime As SYSTEMTIME
  m_Date = Format(Now, "DD-MM-YY")
  udtSystemTime.wYear = Mid(Timespec, 1, 4)
  udtSystemTime.wMonth = Mid(Timespec, 5, 2)
  udtSystemTime.wDay = Mid(Timespec, 7, 2)
  udtSystemTime.wHour = Mid(Timespec, 9, 2)
  udtSystemTime.wMinute = Mid(Timespec, 11, 2)
  udtSystemTime.wSecond = Mid(Timespec, 13, 2)
  udtSystemTime.wMilliseconds = 0
  ' convert system time to local time
  SystemTimeToFileTime udtSystemTime, udtLocalTime
  ' convert local time to GMT
  LocalFileTimeToFileTime udtLocalTime, udtFileTime
  ' open the file to get the filehandle
  lngHandle = CreateFile(Filespec, GENERIC_WRITE, FILE_SHARE_READ Or FILE_SHARE_WRITE, ByVal 0&, OPEN_EXISTING, 0, 0)
  ' change date/time property of the file
  SetFileTime lngHandle, udtFileTime, udtFileTime, udtFileTime
  ' close the handle
  CloseHandle lngHandle
End Sub